|
HP OpenVMS Systemsask the wizard |
|
The Question is: I am running low on disk space on my system disk dka0: for some reason many times causing the system to hang. Is there some why I can decrease the size of the pagefile on the system disk and create a pagefile on another disk to make up the shortfall ? Many Thanks The Answer is :
An obvious potential solution here involves replacing the system disk
with a larger disk.
Insufficient space on the system disk can trigger the auditing subsystem
to take steps to try to reduce the auditing load. See the SET AUDIT
qualifiers /BACKLOG and /RESOURCE for some details.
Both the OPERATOR.LOG (REPLY/NEW_LOG to create a new version) and the
ACCOUNTNG.DAT (SET ACCOUNTING/NEW_FILE to create a new version) files
will grow over time, and these can be periodically recreated and the
older versions then purged as appropriate. This can free disk space.
Other options include moving files off the system disk as appropriate,
and cleaning up unnecessary files (via PURGE and DELETE of files known
to be no longer necessary). Files that can be moved off the system disk
include the pagefile and the swapfile, and (check your OpenVMS version
for specific support restrictions) the sysdump system dump file.
To create a secondary pagefile, use the following commands:
$ CREATE/DIR otherdisk:[SYSEXE]/OWNER=SYSTEM
$ RUN SYS$SYSTEM:SYSGEN
SYSGEN> CREATE otherdisk:[SYSEXE]PAGEFILE.SYS/SIZE=SameAsCurrent
Then see SYS$STARTUP:SYPAGSWPFILES.TEMPLATE and the OpenVMS documentation
for instructions on how to properly modify your system startup command
procedures to install the new pagefile. An example SYPAGSWPFILES.COM
is included below. (The key operations required are the disk MOUNT and
the SYSGEN INSTALL commands -- the procedure could be reduced in size,
but it demonstrates the typical commands required both for the normal
environment, and for the more unusual cases...)
The system disk pagefile and swapfile can be eliminated or reduced in
size. The pagefile and swapfile are required on the system disk only
during OpenVMS upgrades.
In general, all pagefiles should have similar sizes -- having wide
differences in sizing can potentially cause allocation problems and
should be avoided.
--
$! SYPAGSWPFILES.COM
$ SET NOON
$ priv_new == "SYSNAM,VOLPRO,SYSPRV,WORLD,CMKRNL"
$!
$ Write Sys$Output "%SYPAGSWPFILES-I-RUNNING, SYPAGSWPFILES running"
$ priv_old = f$setprv(priv_new)
$ if .not. f$priv(priv_new)
$ Then
$ Write Sys$Output "%SYPAGSWPFILES-F-NOPRIV, insufficient privileges"
$ Write Sys$Output "-SYPAGSWPFILES-I-PRIVS, requires" ''priv_new'"
$ Exit 9
$ Endif
$ Call WAIT_FOR_DISK $10$DKB300:
$! MOUNT the disk if possible...
$ if f$getdvi("$10$DKB300:","EXISTS")
$ then
$ if .not. f$getdvi("$10$DKB300:","MNT")
$ then
$ MOUNT/SYSTEM/NOASSIST $10$DKB300: PAGSWPDSK
$ endif
$ endif
$! INSTALL the pagefiles if possible...
$ if f$getdvi("$10$DKB300:","EXISTS")
$ then
$ if f$getdvi("$10$DKB300:","MNT")
$ Then
$ MCR SYSGEN INSTALL $10$DKB300:[SYSEXE]PAGEFILE.SYS/PAGEFILE
$ Else
$ Write Sys$Output "%SYPAGSWPFILES-W-NOODE, no device mounted..."
$ EndIf
$ Else
$ Write Sys$Output "%SYPAGSWPFILES-W-NOODEEXI, no device exists..."
$ EndIf
$ Write Sys$Output "%SYPAGSWPFILES-I-DONE, procedure done"
$ Exit 1
$WAIT_FOR_DISK: SUBROUTINE
$! some disk devices can potentially take a short while to be configured
$! by OpenVMS during a bootstrap, so we will retry the operation a few
$! times, with a short delay...
$ bomb = 5
$ devnam = "''p1'"
$w4d_retry_loop:
$ If F$GetDVI("''devnam'","EXISTS")
$ Then
$ goto w4d_done_looping
$ EndIf
$ Write Sys$Output "%SYPAGSWPFILES-I-WAITING, Waiting for ''devnam'"
$ txt = f$fao("-SYPAGSWPFILES-I-RETRIES, !SL retr!1%Ey!%Cies!%F remaining", bomb)
$ Write Sys$Output "''txt'"
$ bomb = bomb - 1
$ Wait 00:00:03
$ if bomb .gt. 0
$ then
$ Goto w4d_retry_loop
$ EndIf
$ Write Sys$Output "%SYPAGSWPFILES-E-IGIVEUP, Unable to find ''devnam'"
$ Exit 9
$!
$w4d_done_looping:
$!
$ Exit 1
$ EndSubroutine
|